Les Fonctions de Tri-PLAN :

Ce sont les fonctions utilisables dans les formules contenues dans les objets de type Tableau et Liste. Vous avez accès à ces fonctions dans les deux modes Edition et Utilisation.

lorsque vous entrez des valeurs dans une cellule, une fenêtre de saisie est ouverte. Un nouveau menu “Fonctions” apparaît et vous donne la liste de toutes les fonctions, classées par thèmes. En allant dans ce menu, la fonction choisie est automatiquement recopiée dans la fenêtre de saisie.
Vous pouvez bien entendu entrer les fonctions en tapant directement leur nom, et les majuscules comme les minuscules sont acceptées. La syntaxe est vérifiée et le nom des fonctions est mis en majuscules.

     Utilisation des différents types de valeurs :

Outre les valeurs numériques, Tri-PLAN traite des Booléens, des Dates et des Heures.
Les valeurs de type booléen, date et heure peuvent s’utiliser comme des valeurs numériques. L’équivalence est la suivante :
     - valeurs booléennes : faux = 0 et vrai = 1.
     - date : c’est le nombre de jours depuis le 1/1/1904.
     - heure : c’est le nombre de secondes depuis 0:00:00.
Les valeurs peuvent aussi être une chaîne de caractères et des fonctions spéciales sont prévues pour ces valeurs.

     Les opérateurs sur les valeurs numériques (+, -, *, / ^) :

Tous les opérateurs habituels (^ est l’opérateur puissance) sont valables sur les valeurs numériques.

Exemples :
     3*4 donnera 12.
     3^4 donnera 81.

     Les opérateurs sur les chaînes de caractères :

L’opérateur + s’applique aux chaînes, et effectue la concaténation de deux chaînes.

Exemples :
     “test”+” nouveau” donnera la chaîne “test nouveau”.

     Les opérateurs de comparaison :

Tous ces opérateurs sont valables aussi bien sur les valeurs numériques que sur les chaînes de caractères.
Tri-PLAN dispose des opérateurs = (égal à), < (inférieur à), > (supérieur à) <> (différent de), <= ou =< (inférieur ou égal), >= ou => (supérieur ou égal).
Ces opérateurs retournent une valeur booléenne (1 si vrai, 0 si faux).
Les opérateurs de comparaison sur les chaînes de caractères effectuent des comparaison caractère par caractère (“a” est inférieur à “b”, ...).

Exemples :
     12<25 donnera 1 (vrai)
     “toto”<>”tat” donnera 1 (vrai)
     “bus”>”car” donnera 0 (faux).

          Fonctions Conditionnelles :

     SI(condition;valVrai;valFaux) : Fonction SI conditionnel.

Si la condition est vraie, retourne la première valeur (valVrai). Sinon, retourne la seconde valeur (valFaux).

Exemples :
     SI(17>3;”17 est supérieur à 3”;”Vous êtes sur?”)
     retournera ”17 est supérieur à 3”
     SI(A1<>0; 7/A1;”Division par zéro”)
     retournera la valeur 7 divisé par A1 si A1 est différent de zéro, ou la chaîne ”Division par zéro” dans le cas contraire

     (condition1)ET(condition2) : Fonction ET logique.
Retourne vrai si les deux conditions sont vraies, et faux dans les autres cas.

Exemples :
     (A1>0)ET(A1<100) retournera 0 ou 1 suivant la valeur de A1.

     (condition1)OU(condition2) : Fonction OU logique.
Retourne vrai si une au moins des deux conditions est vraie, et faux si les deux conditions sont fausses.

Exemples :
     (A1>100)OU(A1<-100) retournera 0 ou 1 suivant la valeur de A1.

     NON(condition) : Fonction NON logique.
Retourne vrai si la condition est fausse, et faux si la condition est vraie.

Exemples :
     NON(A1>0) retournera 0 (si A1 est supérieur à 0) ou 1 (si A1 <= 0).

          Fonctions Mathématiques :

     ABS(nombre) : Fonction VALEUR ABSOLUE.
Retourne la valeur absolue de la valeur qui est passée en argument.

Exemples :
     ABS(-7,52) retournera 7,52.

     ALEA() : Fonction ALEATOIRE.
Retourne une valeur aléatoire comprise entre 0 et 1.

     ENTIER(nombre) : Fonction VALEUR ENTIERE.
Retourne la valeur entière du nombre passé en argument.

Exemples :
     ENTIER(7,89) donnera 7.

     EXP(nombre) : Fonction EXPONENTIEL.
Retourne la valeur exponentielle du nombre.

Exemples :
     EXP(7,89) donnera 2670,443911.

     FACTORIELLE(nombre) : Fonction FACTORIELLE.
Retourne la factorielle du nombre. Factorielle de n = 1 * 2 * 3 * ..... * n.

Exemples :
     FACTORIELLE(7) donnera 5040.

     LN(nombre) : Fonction LOGARITHME NEPERIEN.
Retourne le logarithme népérien du nombre.

Exemples :
     LN(7,89) donnera 2,065596.

     LOG10(nombre) : Fonction LOGARITHME (Base 10).
Retourne le logarithme en base 10 du nombre.

Exemples :
     LOG10(7,89) donnera 0,897077.

     MOD(nombre;diviseur) : Fonction MODULO.
Retourne le modulo du nombre divisé par le diviseur, c’est à dire le reste de la division.

Exemples :
     MOD(7,89;2) donnera 1,89.

     RACINE(nombre) : Fonction RACINE CARREE.
Retourne la racine carrée du nombre passé en argument.

Exemples :
     RACINE(7,89) donnera 2,8089.

     SIGNE(nombre) : Fonction SIGNE.
Retourne le signe du nombre, sous la forme :
     -1 si le nombre est négatif, 0 si le nombre est nul et 1 si le nombre est positif.

Exemples :
     SIGNE(7,89) donnera 1
     SIGNE(-7,89) donnera -1.

          Fonctions Trigonométriques :

Pour toutes ces fonctions, les angles doivent être donnés en radians.

     ACOS(nombre) : Fonction ARC COSINUS.
Retourne l’angle dont le cosinus est le nombre passé en argument (fonction inverse de COS).

Exemples :
     ACOS(0,89) donnera 0,473451
     ACOS(COS(0,5)) donnera 0,5.

     ASIN(nombre) : Fonction ARC SINUS.
Retourne l’angle dont le sinus est le nombre passé en argument (fonction inverse de SIN).

Exemples :
     ASIN(0,89) donnera 1,097345
     ASIN(SIN(0,5)) donnera 0,5.

     ATAN(nombre) : Fonction ARC TANGENTE.
Retourne l’angle dont la tangente est le nombre passé en argument (fonction inverse de TAN).

Exemples :
     ATAN(0,89) donnera 0,727262
     ATAN(TAN(0,5)) donnera 0,5.

     COS(angle) : Fonction COSINUS.
Retourne le cosinus de l’angle donné en radians.

Exemples :
     COS(0,89) donnera 0,629412
     COS(PI()) donnera -1.

     PI() : Fonction PI.
Retourne une constante dont la valeur est pi : 3,14.....

     SIN(nombre) : Fonction SINUS.
Retourne le sinus de l’angle donné en radians.

Exemples :
     SIN(0,89) donnera 0,777072
     SIN(PI()/2) donnera 1.

     TAN(nombre) : Fonction TANGENTE.
Retourne la tangente de l’angle donné en radians.

Exemples :
     TAN(0,89) donnera 1,234599
     TAN(PI()/4) donnera 1.

          Fonctions Financières :

Pour toutes les fonctions financières, le taux doit être donné en valeur vraie (10% = 0,1) et en fonction de l’unité de période : 10% par an correspond à 0,1/12 par mois.

     MENSUALITE(capital;nb_périodes;taux) : Fonction MENSUALITE.
Retourne le montant correspondant au remboursement, en un certain nombre de fois (de périodes), d’un capital emprunté à un taux donné.

Exemples :
     J’emprunte 100 000 F à 10% pendant 5 ans, et je veux connaître le remboursement mensuel correspondant, se traduit par :
     MENSUALITE(100000;5*12;10/12/100)
     et donnera un remboursement mensuel de 2 124,70.

     VA(taux;nb_périodes;vers_périodique) : Fonction VALEUR ACTUELLE.
Retourne la valeur actuelle d’un emprunt correspondant à un versement périodique d’un montant fixe pendant n périodes.

Exemples :
     Si je peux rembourser 2 500 F chaque mois pendant 5 ans, combien puis-je emprunter à un taux de 10% ?
     VA(10/12/100;5*12;2500) donnera 117 663,53 F.

     VC(taux;nb_périodes;vers_périodique) : Fonction VALEUR CAPITALISEE.
Retourne la valeur capitalisée d’un versement périodique à un taux donné, c’est à dire la valeur qu’aura cet investissement au bout d’un certain nombre d’années.

Exemples :
     Si je place 2 500 F chaque mois sur un compte me rapportant 10% par an, de combien disposerai-je dans 5 ans ?
     VC(10/12/100;5*12;2500) donnera 195 205,95 F.

          Fonctions Statistiques :

Ces fonctions traitent un groupe de cellules du même objet (ou d’un autre objet). Dans les exemples qui suivent, on considère que les cellules A1 à B2 on les valeurs suivantes :
     A1 = 7,35
     B1 = -3
     A2 = 8
     B2 = 2;

     MAX(bloc_valeurs) : Fonction VALEUR MAXI.
Retourne la valeur maximale du groupe de cellules.

Exemples :
     MAX(A1:B2) donnera 8.

     MIN(bloc_valeurs) : Fonction VALEUR MINI.
Retourne la valeur minimale du groupe de cellules.

Exemples :
     MIN(A1:B2) donnera -3.

     MOYENNE(bloc_valeurs) : Fonction VALEUR MOYENNE.
Retourne la valeur maximale du groupe de cellules.

Exemples :
     MOYENNE(A1:B2) donnera 3,5875.

     NB(bloc_valeurs) : Fonction NOMBRE DE VALEURS.
Retourne le nombre de cellules contenant une valeur numérique.

Exemples :
     NB(A1:B2) donnera 4.

     SOMME(bloc_valeurs) : Fonction SOMME DES VALEURS.
Retourne la somme des valeurs du groupe de cellules.

Exemples :
     SOMME(A1:B2) donnera 14,35.

          Fonctions Calendaires :

Ces fonctions concernent les dates et les heures.
Rappelons que les dates sont codées comme un nombre de jours depuis le 1/1/1904, et les heures comme le nombre de secondes depuis 0:00:00.

     ANNEE(date) : Fonction ANNEE.
Retourne l’année de la date passée en argument.

Exemples :
     ANNEE(0) donnera 1904
     ANNEE(25000) donnera 1972 (puisque le 25.000ème jour après le 1/1/1904 est le 12/6/72).
     ANNEE(DATEDUJOUR()) donnera 1993.

     DATE(année;mois;jour) : Fonction DATE.
Retourne la date dont la décomposition est donnée en arguments.

Exemples :
     DATE(87;3;21) donnera le 21/03/87.

     DATEDUJOUR() : Fonction DATE DE CE JOUR.
Retourne une constante : la date d’aujourd’hui.

     HEURE(heures;minutes;secondes) : Fonction HEURE.
Retourne l’heure dont la décomposition est donnée en arguments. Transforme donc ces arguments en un nombre de secondes.

Exemples :
     HEURE(17;3;21) donnera 5:03:21 pm.

     HEUREDUJOUR() :    Fonction HEURE ACTUELLE.
Retourne une constante : l’heure actuelle.

     JOUR(date) : Fonction JOUR.
Retourne le jour du mois de la date passée en argument (donc une valeur de 1 à 31).

Exemples :
     JOUR(25000) donnera 12.

     MINUTES(heure) :     Fonction NOMBRE DE MINUTES.
Retourne le nombre de minutes dans l’heure passée (donc un nombre entre 0 et 59).

Exemples :
     MINUTES( HEURE(17;3;21)) donnera 3.

     MOIS(date) : Fonction NUMERO DU MOIS.
Retourne le numéro du mois de la date, donc une valeur comprise entre 1 et 12.

Exemples :
     MOIS(25000) donnera 6.

     NBHEURES(heure) : Fonction NOMBRE D’HEURES.
Retourne le nombre d’heures dans l’heure passée.

Exemples :
     NBHEURES(HEURE(17;3;21)) donnera 17.

     NUMJOUR(date) : Fonction JOUR DE LA SEMAINE.
Retourne le numéro du jour dans la semaine, pour la date passée en argument. La numérotation commence par la valeur 1 pour le Dimanche, se poursuit par 2 le Lundi, 3 le Mardi, etc.., et se termine par 7 le Samedi.
Pour connaître le jour de la semaine correspondant à une date particulière, vous pouvez utiliser cette fonction associée à la fonction DATE()

Exemples :
     NUMJOUR(DATE(93;12;25)) donnera 7 (Noël est un Samedi cette année).
     NUMJOUR(25000) donnera 2 (c’était un Lundi).

     SECONDES(heure) : Fonction NOMBRE DE SECONDES.
Retourne le nombre de secondes de l’heure passée en argument (donc une valeur entre 0 et 59).

Exemples :
     SECONDES(HEURE(17;3;21)) donnera 21.

          Fonctions sur les chaîne de caractères :

     CHAINE(nombre;nb_décimales) : Fonction CONVERSION EN CHAINE.
Convertit un nombre en une chaîne de caractères, avec le nombre de décimales spécifié.

Exemples :
     CHAINE(PI();3) donnera “3,142”.

     CHAINEDATE(date) : Fonction CONVERSION EN CHAINE.
Convertit une date en chaîne de caractères.

Exemples :
     CHAINEDATE(25000) donnera “12/06/72”.

     CHAINEHEURE(heure) : Fonction CONVERSION EN CHAINE.
Convertit une heure en chaîne de caractères.

Exemples :
     CHAINEHEURE(25000) donnera “6:56:40”.

     LONGUEUR(chaîne) : Fonction LONGUEUR D’UNE CHAINE.
Retourne le nombre de caractères contenus dans la chaîne.

Exemples :
     LONGUEUR(“Bonjour”) donnera 7.

     SOUSCHAINE(chaîne;debut;nombre) : Fonction EXTRACTION DE CHAINE.
Retourne une chaîne de caractères qui est une partie de la chaîne d’origine, commençant au caractère “debut” et contenant “nombre” caractères. Si nombre est trop grand, la chaîne sera tronquée à la fin de la chaîne d’origine.

Exemples :
     SOUSCHAINE(“Bonjour”;4;3) donnera “jou”.

     TROUVE(chaîne;texte_cherché;début) : Fonction RECHERCHE DE CHAINE.
Retourne la position du texte recherché dans la chaîne, à partir de la position “debut”.

Exemples :
     TROUVE(“Bonjour”;”jo”;1) donnera 4.

          Fonctions sur les éléments des objets Liste :

Ces fonctions ne s’appliquent qu’aux objets de type Liste. Par contre, une cellule d’un Tableau peut très bien contenir, da,s une formule, une de ces fonctions.
Ces fonctions ne sont réellement utilisables qu’en mode Utilisation.
Le numéro du bloc (c’est-à-dire le numéro de l’objet de type Liste) indique l’objet à traiter. Ce numéro peut être mis à la valeur 0 (zéro) si la formule se trouve dans le même objet Liste.

     NBELEMENTS(num_bloc) : Fonction NOMBRE D’ELEMENTS D’UNE LISTE.
Retourne le nombre d’éléments dans un objet Liste.

Exemples :
     NBELEMENTS(0) dans un objet Liste contenant 12 éléments donnera 12.

     MAXLISTE(num_bloc;champs) : Fonction VALEUR MAXI DES ELEMENTS D’UNE LISTE.
Retourne la valeur maximale des cellules (ou groupes de cellules) de tous les éléments de l’objet Liste.

Exemples :
     Si on veut avoir la valeur maximale contenue dans la cellule B1 de l’objet Liste numéro 2 :
     MAXLISTE(2;#2:/N:$B$1)

     MINLISTE(num_bloc;champs) : Fonction VALEUR MINI DES ELEMENTS D’UNE LISTE.
Retourne la valeur minimale des cellules (ou groupes de cellules) de tous les éléments de l’objet Liste.

Exemples :
     Si on veut avoir la valeur minimale contenue dans la cellule B1 de l’objet Liste numéro 2 :
     MINLISTE(2;#2:/N:$B$1)

     NBLISTE(num_bloc;champs) : Fonction NOMBRE DE VALEURS DANS UNE LISTE.
Retourne le nombre de cellules contenant une valeur numérique dans les cellules (ou groupes de cellules) de tous les éléments de l’objet Liste.

Exemples :
     Si on veut avoir le nombre de cellules B1 de l’objet Liste numéro 2 contenant une valeur :
     NBLISTE(2;#2:/N:$B$1)

     SOMMELISTE(num_bloc;champs) : Fonction SOMME DES VALEURS D’UNE LISTE.
Retourne la somme des valeurs numériques des cellules (ou groupes de cellules) de tous les éléments de l’objet Liste.

Exemples :
     Si on veut avoir la somme des cellules B1 de l’objet Liste numéro 2 :
     SOMMELISTE(2;#2:/N:$B$1)

          Fonctions sur les Fiches :

Ces fonctions ne sont appliquables qu’en mode Utilisation.

     NBFICHES() : Fonction NOMBRE DE FICHES.
Retourne le nombre total de fiches pour le document en cours (et le niveau en cours).

     NUMFICHE() : Fonction NUMERO DE LA FICHE.
Retourne le numéro de la fiche en cours.

          Fonctions Diverses :

     COLONNE() : Fonction NUMERO DE LA COLONNE.
Retourne le numéro de la colonne dans laquelle se trouve la cellule contenant cette formule (numéro de 1 à ...).

     LIGNE() : Fonction NUMERO DE LA LIGNE.
Retourne le numéro de la ligne dans laquelle se trouve la cellule contenant cette formule (numéro de 1 à ...).

     NBBLOCS() : Fonction NOMBRE D’OBJETS.
Retourne le nombre de blocs (d’objets) de la feuille en cours.

     NUMBLOC() : Fonction NUMERO DE CET OBJET.
Retourne le numéro du bloc (de l’objet) contenant cette formule.